Contract Name:
OrderManager
Contract Source Code:
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.26;
/* solhint-disable private-vars-leading-underscore */
/* solhint-disable var-name-mixedcase */
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "@openzeppelin/contracts/interfaces/IERC1271.sol";
import "@openzeppelin/contracts/interfaces/IERC165.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "./IOrderManager.sol";
import "./IDLF.sol";
import "./OrderManagerErrors.sol";
import "../SingleAdminAccessControl.sol";
/**
* @title OrderManager
* @notice This contract manages buy and redeem orders for DLF tokens, the RWA fund token backed by tokenized treasuries
*
* @dev System Overview:
* The OrderManager is part of the DLF platform's settlement system that handles execution
* of tokenized fund orders with two distinct settlement paths:
*
* **Mint Orders (Atomic Settlement)**:
* 1. Order Creation: Backend RFQ system creates order with quoted rates, signed by user (EIP-712)
* 2. Immediate Execution: Orders are submitted and DLF tokens are minted atomically based on accepted quote
* 3. Collateral Transfer: User's collateral is transferred to custody wallets for off-chain processing
*
* **Redeem Orders (Batch Settlement)**:
* 1. Order Creation: Backend RFQ system creates order, signed by user (EIP-712)
* 2. Order Submission: Orders are submitted through redeem function
* 3. DLF Burn: DLF tokens are burned from benefactor on Order Submission
* 4. Daily Settlement: Orders are batched and settled once daily by authorized operators
* 5. Collateral Distribution: After on-ramping collateral, funds are distributed from custodian wallets to beneficiaries
*
* Key Design Principles:
* - **Regulatory Compliance**: Hybrid settlement model balances immediate token issuance with compliant off-chain asset management
* - **Access Control**: Role-based permissions ensure only authorized parties can execute settlements
* - **Signature Verification**: EIP-712 signatures prevent unauthorized order execution
* - **Collateral Isolation**: Different collateral assets (USDC, TRYTF) are handled appropriately
*
* Note: While mint orders provide immediate on-chain token issuance, redeem orders are settled
* asynchronously through batch processing.
*/
contract OrderManager is IOrderManager, SingleAdminAccessControl, ReentrancyGuard {
using SafeERC20 for IERC20;
using EnumerableSet for EnumerableSet.AddressSet;
using OrderManagerErrors for string;
/* --------------- CONSTANTS --------------- */
/// @notice EIP712 domain
bytes32 private constant EIP712_DOMAIN =
keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");
/// @notice order type
bytes32 private constant ORDER_TYPE = keccak256(
"Order(string order_id,uint8 order_type,uint120 expiry,uint128 nonce,address benefactor,address beneficiary,address collateral_asset,uint128 token_in_amount,uint128 estimated_token_out_amount,uint128 fx_rate_approximate,bytes32 terms_hash,uint8 guarantee_type)"
);
/// @notice role enabling to invoke mint
bytes32 private constant MINTER_ROLE = keccak256("MINTER_ROLE");
/// @notice role enabling to invoke redeem
bytes32 private constant REDEEMER_ROLE = keccak256("REDEEMER_ROLE");
/// @notice role enabling to transfer collateral to custody wallets
bytes32 private constant COLLATERAL_MANAGER_ROLE = keccak256("COLLATERAL_MANAGER_ROLE");
/// @notice role enabling to disable mint and redeem and remove minters and redeemers in an emergency
bytes32 private constant GATEKEEPER_ROLE = keccak256("GATEKEEPER_ROLE");
/// @notice EIP 1271 magic value hash
bytes4 private constant EIP1271_MAGICVALUE = bytes4(keccak256("isValidSignature(bytes32,bytes)"));
/// @notice address denoting native ether
address private constant NATIVE_TOKEN = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
/// @notice EIP712 name
bytes32 private constant EIP_712_NAME = keccak256("OrderManager");
/// @notice holds EIP712 revision
bytes32 private constant EIP712_REVISION = keccak256("1");
/* --------------- STATE VARIABLES --------------- */
/// @notice DLF token
IDLF public dlf;
/// @notice whitelisted benefactors
EnumerableSet.AddressSet private _whitelistedBenefactors;
/// @notice approved beneficiaries for a given benefactor
mapping(address => EnumerableSet.AddressSet) private _approvedBeneficiariesPerBenefactor;
/// @notice settlement vehicle addresses
EnumerableSet.AddressSet private _settlementVehicleAddresses;
/// @notice holds computable chain id
uint256 private immutable _chainId;
/// @notice holds computable domain separator
bytes32 private immutable _domainSeparator;
/// @notice user deduplication
mapping(address => mapping(uint256 => uint256)) private _orderBitmaps;
/// @notice configurations per token asset
mapping(address => TokenConfig) public tokenConfig;
/* --------------- CONSTRUCTOR --------------- */
constructor(
address[] memory _assets,
TokenConfig[] memory _tokenConfig,
address[] memory _settlementVehicles,
address _admin
) ReentrancyGuard() {
if (_tokenConfig.length == 0) revert NoAssetsProvided();
if (_assets.length == 0) revert NoAssetsProvided();
if (_admin == address(0)) revert InvalidZeroAddress();
_grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
// Ensure every token config has an asset key
if (_tokenConfig.length != _assets.length) {
revert InvalidAssetAddress();
}
// Set the max mint/redeem limits per block for each asset
for (uint128 k = 0; k < _tokenConfig.length;) {
if (tokenConfig[_assets[k]].isActive || _assets[k] == address(0)) {
revert InvalidAssetAddress();
}
_setTokenConfig(_assets[k], _tokenConfig[k]);
unchecked {
++k;
}
}
// Initialize settlement vehicle addresses
for (uint128 j = 0; j < _settlementVehicles.length;) {
addSettlementVehicleAddress(_settlementVehicles[j]);
unchecked {
++j;
}
}
if (msg.sender != _admin) {
_grantRole(DEFAULT_ADMIN_ROLE, _admin);
}
_chainId = block.chainid;
_domainSeparator = _computeDomainSeparator();
}
/* --------------- EXTERNAL --------------- */
/**
* @notice Fallback function to receive ether
*/
receive() external payable {
emit Received(msg.sender, msg.value);
}
/**
* @notice Atomically mint DLF tokens by executing a user-accepted RFQ quote from the backend
* @dev Never-fail pattern with failsafe exception: This function emits OrderFailed on validation/transfer
* failures and follows the never-fail pattern for all validations. However, the DLF mint operation
* itself is allowed to revert as a failsafe mechanism. The backend simulates all transactions before
* execution, so DLF mint failures should never occur in practice. If a mint does fail after collateral
* transfer, it indicates a critical unexpected state (race condition, blacklist, etc.) that warrants
* immediate transaction rollback to protect user funds rather than silently failing.
* Immediately mints DLF tokens based on the guaranteed quote in the order
* @param order struct containing order details with GUARANTEE type
* @param signature signature of the taker
* @param settlementContract address that will receive the collateral payment
*/
function mint(Order calldata order, Signature calldata signature, address settlementContract)
external
override
nonReentrant
onlyRole(MINTER_ROLE)
{
// Validate order
string memory validationError = _validateMintOrder(order, signature, settlementContract);
if (bytes(validationError).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, validationError);
return;
}
_createMintOrder(order, settlementContract);
}
/**
* @notice Create a redeem order to burn DLF tokens from benefactor, and return collateral to beneficiary
* @dev Never-fail pattern with failsafe exception: This function emits OrderFailed on validation failures
* and follows the never-fail pattern for all validations. However, the DLF burn operation itself is
* allowed to revert as a failsafe mechanism. The backend simulates all transactions before execution,
* so DLF burn failures should never occur in practice. If a burn does fail, it indicates a critical
* unexpected state (transfer paused, blacklist, etc.) that warrants immediate transaction rollback.
* Burns DLF tokens from order.benefactor (the address sending DLF for redemption).
* @param order struct containing order details and confirmation from server
* @param signature signature of the taker
* @param settlementContract address that will receive the DLF token payment
*/
function redeem(Order calldata order, Signature calldata signature, address settlementContract)
external
override
nonReentrant
onlyRole(REDEEMER_ROLE)
{
// Validate order
string memory validationError = _validateRedeemOrder(order, signature, settlementContract);
if (bytes(validationError).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, validationError);
return;
}
_createRedeemOrder(order, settlementContract);
}
/**
* @notice Atomically mint DLF tokens by executing a user-accepted RFQ quote from the backend with gasless approval
* @dev Never-fail pattern with failsafe exception: This function emits OrderFailed on validation/permit/transfer
* failures and follows the never-fail pattern for all validations. However, the DLF mint operation
* itself is allowed to revert as a failsafe mechanism. The backend simulates all transactions before
* execution, so DLF mint failures should never occur in practice. If a mint does fail after collateral
* transfer, it indicates a critical unexpected state (race condition, blacklist, etc.) that warrants
* immediate transaction rollback to protect user funds rather than silently failing.
* Immediately mints DLF tokens based on the guaranteed quote in the order
* @param order struct containing order details with GUARANTEE type
* @param signature signature of the taker
* @param settlementContract address that will receive the collateral payment
* @param permitParams permit signature parameters for gasless approval
*/
function mintWithApproval(
Order calldata order,
Signature calldata signature,
address settlementContract,
PermitParams calldata permitParams
)
external
override
nonReentrant
onlyRole(MINTER_ROLE)
{
// Validate order
string memory validationError = _validateMintOrder(order, signature, settlementContract);
if (bytes(validationError).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, validationError);
return;
}
// Execute permit
string memory permitFailureReason = _handlePermitExecution(
order.collateral_asset,
order.benefactor,
order.token_in_amount,
permitParams
);
if (bytes(permitFailureReason).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, permitFailureReason);
return;
}
_createMintOrder(order,settlementContract);
}
/**
* @notice Create a redeem order to burn DLF tokens from benefactor, and return collateral to beneficiary
* with gasless approval for the collateral asset
* @dev Never-fail pattern with failsafe exception: This function emits OrderFailed on validation/permit failures
* and follows the never-fail pattern for all validations. However, the DLF burn operation itself is
* allowed to revert as a failsafe mechanism. The backend simulates all transactions before execution,
* so DLF burn failures should never occur in practice. If a burn does fail, it indicates a critical
* unexpected state (transfer paused, blacklist, etc.) that warrants immediate transaction rollback.
* Burns DLF tokens from order.benefactor (the address sending DLF for redemption).
* @param order struct containing order details and confirmation from server
* @param signature signature of the taker
* @param settlementContract address that will receive the DLF token payment
* @param permitParams permit signature parameters for gasless approval
*/
function redeemWithApproval(
Order calldata order,
Signature calldata signature,
address settlementContract,
PermitParams calldata permitParams
)
external
override
nonReentrant
onlyRole(REDEEMER_ROLE)
{
// Validate order
string memory validationError = _validateRedeemOrder(order, signature, settlementContract);
if (bytes(validationError).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, validationError);
return;
}
// Execute permit
string memory permitFailureReason = _handlePermitExecution(
address(dlf),
order.benefactor,
order.token_in_amount,
permitParams
);
if (bytes(permitFailureReason).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, permitFailureReason);
return;
}
_createRedeemOrder(order, settlementContract);
}
/**
* @notice Disables the mint and redeem order creation
*/
function disableMintRedeem() external onlyRole(GATEKEEPER_ROLE) {
emit DisableMintRedeem(msg.sender);
}
/**
* @notice transfers an asset to a custody wallet
* @param wallet The custody wallet address
* @param asset The asset to transfer
* @param amount The amount to transfer
*/
function transferToCustody(address wallet, address asset, uint128 amount)
external
nonReentrant
onlyRole(COLLATERAL_MANAGER_ROLE)
{
if (wallet == address(0) || !_settlementVehicleAddresses.contains(wallet)) revert InvalidAddress();
if (asset == NATIVE_TOKEN) {
(bool success,) = wallet.call{value: amount}("");
if (!success) revert TransferFailed();
} else {
IERC20(asset).safeTransfer(wallet, amount);
}
emit CustodyTransfer(wallet, asset, amount);
}
/**
* @notice Removes an asset from the supported assets list
* @param asset The asset address to remove
*/
function removeSupportedAsset(address asset) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (!tokenConfig[asset].isActive) revert InvalidAssetAddress();
delete tokenConfig[asset];
emit AssetRemoved(asset);
}
/**
* @notice Checks if an asset is supported
* @param asset The asset address to check
* @return True if the asset is supported, false otherwise
*/
function isSupportedAsset(address asset) external view returns (bool) {
return tokenConfig[asset].isActive;
}
/**
* @notice Removes the minter role from an account, this can ONLY be executed by the gatekeeper role
* @param minter The address to remove the minter role from
*/
function removeMinterRole(address minter) external onlyRole(GATEKEEPER_ROLE) {
_revokeRole(MINTER_ROLE, minter);
}
/**
* @notice Removes the redeemer role from an account, this can ONLY be executed by the gatekeeper role
* @param redeemer The address to remove the redeemer role from
*/
function removeRedeemerRole(address redeemer) external onlyRole(GATEKEEPER_ROLE) {
_revokeRole(REDEEMER_ROLE, redeemer);
}
/**
* @notice Removes the collateral manager role from an account, this can ONLY be executed by the gatekeeper role
* @param collateralManager The address to remove the collateralManager role from
*/
function removeCollateralManagerRole(address collateralManager) external onlyRole(GATEKEEPER_ROLE) {
_revokeRole(COLLATERAL_MANAGER_ROLE, collateralManager);
}
/**
* @notice Removes the benefactor address from the benefactor whitelist
* @param benefactor The benefactor address to remove
*/
function removeWhitelistedBenefactor(address benefactor) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (!_whitelistedBenefactors.remove(benefactor)) revert InvalidAddress();
emit BenefactorRemoved(benefactor);
}
/* --------------- PUBLIC --------------- */
/**
* @notice Adds a settlement vehicle address to the settlement vehicle whitelist
* @param settlementVehicle The settlement vehicle address to add
*/
function addSettlementVehicleAddress(address settlementVehicle) public onlyRole(DEFAULT_ADMIN_ROLE) {
if (settlementVehicle == address(0) || settlementVehicle == address(dlf) || settlementVehicle == address(this) || !_settlementVehicleAddresses.add(settlementVehicle)) {
revert InvalidSettlementVehicleAddress();
}
emit SettlementVehicleAddressAdded(settlementVehicle);
}
/**
* @notice Removes a settlement vehicle address from the settlement vehicle whitelist
* @param settlementVehicle The settlement vehicle address to remove
*/
function removeSettlementVehicleAddress(address settlementVehicle) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (!_settlementVehicleAddresses.remove(settlementVehicle)) {
revert InvalidSettlementVehicleAddress();
}
emit SettlementVehicleAddressRemoved(settlementVehicle);
}
/**
* @notice Returns whether an address is a settlement vehicle
* @param settlementVehicle The address to check
* @return True if the address is a settlement vehicle, false otherwise
*/
function isSettlementVehicleAddress(address settlementVehicle) public view returns (bool) {
return _settlementVehicleAddresses.contains(settlementVehicle);
}
/**
* @notice Adds a benefactor address to the benefactor whitelist
* @param benefactor The benefactor address to add
*/
function addWhitelistedBenefactor(address benefactor) public onlyRole(DEFAULT_ADMIN_ROLE) {
if (benefactor == address(0) || !_whitelistedBenefactors.add(benefactor)) {
revert InvalidBenefactorAddress();
}
emit BenefactorAdded(benefactor);
}
/**
* @notice Adds a beneficiary address to the approved beneficiaries list
* @notice Only the benefactor can add or remove corresponding beneficiaries
* @param beneficiary The beneficiary address
* @param status The status of the beneficiary, true to be added, false to be removed
*/
function setApprovedBeneficiary(address beneficiary, bool status) public {
if (beneficiary == address(0)) revert InvalidBeneficiaryAddress();
if (status) {
if (!_approvedBeneficiariesPerBenefactor[msg.sender].add(beneficiary)) {
revert InvalidBeneficiaryAddress();
} else {
emit BeneficiaryAdded(msg.sender, beneficiary);
}
} else {
if (!_approvedBeneficiariesPerBenefactor[msg.sender].remove(beneficiary)) {
revert InvalidBeneficiaryAddress();
} else {
emit BeneficiaryRemoved(msg.sender, beneficiary);
}
}
}
/**
* @notice Get the domain separator for the token
* @dev Return cached value if chainId matches cache, otherwise recomputes separator, to prevent replay attack across forks
* @return The domain separator of the token at current chain
*/
function getDomainSeparator() public view returns (bytes32) {
if (block.chainid == _chainId) {
return _domainSeparator;
}
return _computeDomainSeparator();
}
/**
* @notice hash an Order struct
* @param order The order to hash
* @return The hash of the order
*/
function hashOrder(Order calldata order) public view override returns (bytes32) {
return ECDSA.toTypedDataHash(getDomainSeparator(), keccak256(encodeOrder(order)));
}
/**
* @notice Encode an Order struct for hashing
* @param order The order to encode
* @return The encoded order data
*/
function encodeOrder(Order calldata order) public pure returns (bytes memory) {
return abi.encode(
ORDER_TYPE,
keccak256(bytes(order.order_id)),
order.order_type,
order.expiry,
order.nonce,
order.benefactor,
order.beneficiary,
order.collateral_asset,
order.token_in_amount,
order.estimated_token_out_amount,
order.fx_rate_approximate,
order.terms_hash,
order.guarantee_type
);
}
/**
* @notice assert validity of signed order
* @dev Returns empty string if valid, error message if invalid (never reverts)
* @param order The order to verify
* @param signature The signature to verify
* @return Empty string if valid, error message if invalid
*/
function verifyOrder(Order calldata order, Signature calldata signature)
public
view
returns (string memory)
{
bytes32 taker_order_hash = hashOrder(order);
if (signature.signature_type == SignatureType.EIP712) {
// Use tryRecover to gracefully handle malformed signatures without reverting
(address signer, ECDSA.RecoverError error) = ECDSA.tryRecover(
taker_order_hash,
signature.signature_bytes
);
// Check for signature recovery errors (invalid length, 's' value, 'v' value, etc.)
if (error != ECDSA.RecoverError.NoError) {
return OrderManagerErrors.INVALID_SIGNATURE_FORMAT;
}
// Check if recovered signer matches benefactor
if (signer != order.benefactor) {
return OrderManagerErrors.INVALID_EIP712_SIGNATURE;
}
} else if (signature.signature_type == SignatureType.EIP1271) {
try IERC1271(order.benefactor).isValidSignature(taker_order_hash, signature.signature_bytes) returns (bytes4 result) {
if (result != EIP1271_MAGICVALUE) {
return OrderManagerErrors.INVALID_EIP1271_SIGNATURE;
}
} catch {
return OrderManagerErrors.EIP1271_VALIDATION_FAILED;
}
} else {
return OrderManagerErrors.UNKNOWN_SIGNATURE_TYPE;
}
if (!_whitelistedBenefactors.contains(order.benefactor)) {
return OrderManagerErrors.BENEFACTOR_NOT_WHITELISTED;
}
if (order.benefactor != order.beneficiary) {
if (!_approvedBeneficiariesPerBenefactor[order.benefactor].contains(order.beneficiary)) {
return OrderManagerErrors.BENEFICIARY_NOT_APPROVED;
}
}
// For mint orders, native ETH is not supported
if (order.order_type == OrderType.MINT && order.collateral_asset == NATIVE_TOKEN) return OrderManagerErrors.UNSUPPORTED_ASSET;
// Validate hash added to order
if (order.terms_hash == bytes32(0)) return OrderManagerErrors.INVALID_TERMS_HASH;
// Check if asset is active in token config
if (!tokenConfig[order.collateral_asset].isActive) return OrderManagerErrors.UNSUPPORTED_ASSET;
if (order.beneficiary == address(0)) return OrderManagerErrors.INVALID_ADDRESS;
if (order.token_in_amount == 0 || order.estimated_token_out_amount == 0) return OrderManagerErrors.INVALID_AMOUNT;
if (order.fx_rate_approximate == 0 || order.fx_rate_approximate > 1000e8) return OrderManagerErrors.INVALID_FX_RATE;
if (block.timestamp > order.expiry) return OrderManagerErrors.SIGNATURE_EXPIRED;
return ""; // All validations passed
}
/**
* @notice verify validity of nonce by checking its presence
* @param sender The address that owns the nonce
* @param nonce The nonce to verify
* @return errorMessage Error message if validation fails, empty string if successful
* @return invalidatorSlot The slot in the bitmap
* @return invalidator The current bitmap value
* @return invalidatorBit The bit position for this nonce
*/
function verifyNonce(address sender, uint128 nonce)
public
view
override
returns (string memory errorMessage, uint128, uint256, uint256)
{
if (nonce == 0) {
return (OrderManagerErrors.INVALID_NONCE, 0, 0, 0);
}
uint128 invalidatorSlot = uint64(nonce) >> 8;
uint256 invalidatorBit = 1 << uint8(nonce);
uint256 invalidator = _orderBitmaps[sender][invalidatorSlot];
if (invalidator & invalidatorBit != 0) {
return (OrderManagerErrors.NONCE_ALREADY_USED, 0, 0, 0);
}
return ("", invalidatorSlot, invalidator, invalidatorBit);
}
/* --------------- PRIVATE --------------- */
/**
* @notice Process an order after all validations have passed
* @dev Internal function that handles common order processing logic for both mint and redeem
* @param order The order to process
* @param settlementContract The settlement contract address
* @param amount The token amount to transfer (collateral for mint, DLF for redeem)
* @param assetAddress The token address to transfer (collateral asset for mint, DLF for redeem)
* @return Empty string if successful, error message if failed
*/
function _processOrder(
Order calldata order,
address settlementContract,
uint128 amount,
address assetAddress
) private returns (string memory) {
string memory nonceError = _deduplicateOrder(order.benefactor, order.nonce);
if (bytes(nonceError).length > 0) {
return nonceError;
}
if (assetAddress != address(dlf)) {
if (!_transferTokens(amount, assetAddress, order.benefactor, settlementContract)) {
return OrderManagerErrors.TRANSFER_FAILED;
}
}
return "";
}
/**
* @notice Validate a mint order
* @dev Returns empty string if valid, error message if invalid
* @param order The order to validate
* @param signature The order signature
* @param settlementContract The settlement contract address
* @return failureReason Empty string if valid, error message otherwise
*/
function _validateMintOrder(
Order calldata order,
Signature calldata signature,
address settlementContract
) private view returns (string memory failureReason) {
// Check DLF token is initialized before processing mint orders
if (address(dlf) == address(0)) {
return OrderManagerErrors.DLF_NOT_INITIALIZED;
}
if (!_settlementVehicleAddresses.contains(settlementContract)) {
return OrderManagerErrors.INVALID_SETTLEMENT_VEHICLE;
}
if (order.order_type != OrderType.MINT) {
return OrderManagerErrors.INVALID_ORDER_TYPE;
}
return verifyOrder(order, signature);
}
/**
* @notice Validate a redeem order
* @dev Returns empty string if valid, error message if invalid
* @param order The order to validate
* @param signature The order signature
* @param settlementContract The settlement contract address
* @return failureReason Empty string if valid, error message otherwise
*/
function _validateRedeemOrder(
Order calldata order,
Signature calldata signature,
address settlementContract
) private view returns (string memory failureReason) {
// Check DLF token is initialized before processing redeem orders
if (address(dlf) == address(0)) {
return OrderManagerErrors.DLF_NOT_INITIALIZED;
}
if (!_settlementVehicleAddresses.contains(settlementContract)) {
return OrderManagerErrors.INVALID_SETTLEMENT_VEHICLE;
}
if (order.order_type != OrderType.REDEEM) {
return OrderManagerErrors.INVALID_ORDER_TYPE;
}
return verifyOrder(order, signature);
}
/**
* @notice deduplication of taker order
* @param sender The address of the order sender
* @param nonce The nonce to deduplicate
*/
function _deduplicateOrder(address sender, uint128 nonce) private returns (string memory) {
(string memory errorMessage, uint128 invalidatorSlot, uint256 invalidator, uint256 invalidatorBit)
= verifyNonce(sender, nonce);
if (bytes(errorMessage).length > 0) {
return errorMessage;
}
_orderBitmaps[sender][invalidatorSlot] = invalidator | invalidatorBit;
return "";
}
/**
* @notice Validates permit parameters - safe version that returns failure reason
* @param requiredAmount The minimum required permit amount
* @param permitParams The permit parameters to validate
* @return Empty string if valid, error message if invalid
*/
function _validatePermitParamsSafe(
uint128 requiredAmount,
PermitParams calldata permitParams
) private view returns (string memory) {
// Validate permit amount is sufficient
if (permitParams.value < requiredAmount) {
return OrderManagerErrors.PERMIT_AMOUNT_INSUFFICIENT;
}
// Validate permit deadline is not expired
if (permitParams.deadline < block.timestamp) {
return OrderManagerErrors.PERMIT_DEADLINE_INVALID;
}
return ""; // Validation passed
}
/**
* @notice Safely executes permit call on the specified token - never reverts
* @param token The token address to execute permit on
* @param signer The owner of the tokens (benefactor)
* @param permitParams The permit parameters
* @return success True if permit execution succeeded, false otherwise
*/
function _executePermit(
address token,
address signer,
PermitParams calldata permitParams
) private returns (bool success) {
try IERC20Permit(token).permit(
signer,
address(this),
permitParams.value,
permitParams.deadline,
permitParams.v,
permitParams.r,
permitParams.s
) {
return true;
} catch {
return false;
}
}
/* --------------- INTERNAL --------------- */
/**
* @notice transfer tokens to payment receiver - never reverts
* @param amount The amount to transfer
* @param asset The asset to transfer
* @param benefactor The benefactor (token owner)
* @param settlementContract The settlement contract to receive tokens
* @return success True if transfer succeeded, false otherwise
*/
function _transferTokens(uint128 amount, address asset, address benefactor, address settlementContract) internal returns (bool success) {
try IERC20(asset).transferFrom(benefactor, settlementContract, amount) returns (bool result) {
return result;
} catch {
return false;
}
}
/**
* @notice Internal function to handle common mint order logic
* @dev Follows never-fail pattern for validation/transfer errors but allows DLF mint to revert as failsafe.
* The backend simulates transactions before execution, so mint failures should never occur in practice.
* If a mint does fail, it indicates an unexpected critical issue warranting transaction revert.
* @param order The order to process
* @param settlementContract The settlement contract address
*/
function _createMintOrder(Order calldata order, address settlementContract) internal {
string memory failureReason = _processOrder(
order,
settlementContract,
order.token_in_amount,
order.collateral_asset
);
if (bytes(failureReason).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, failureReason);
return;
}
// IMPORTANT: This mint call is allowed to revert (failsafe exception to never-fail pattern)
// Rationale: Backend simulates all transactions before execution, so this should never fail in practice.
// If it does fail after collateral transfer, it indicates an unexpected critical state (race condition,
// sudden blacklist, etc.) that requires immediate rollback to protect user funds. Silently failing would
// leave user collateral transferred without DLF tokens issued.
dlf.mint(order.beneficiary, order.estimated_token_out_amount);
emit BuyOrderCreated(
order.order_id,
order.benefactor,
order.beneficiary,
msg.sender,
order.collateral_asset,
order.token_in_amount,
order.estimated_token_out_amount,
order.fx_rate_approximate,
order.terms_hash,
GuaranteeType.GUARANTEE
);
}
/**
* @notice Internal function to handle common redeem order logic
* @param order The order to process
* @param settlementContract The settlement contract address
*/
function _createRedeemOrder(Order calldata order, address settlementContract) internal {
string memory failureReason = _processOrder(order, settlementContract, order.token_in_amount, address(dlf));
if (bytes(failureReason).length > 0) {
emit OrderFailed(order.order_id, order.beneficiary, failureReason);
return;
}
// IMPORTANT: This burn call is allowed to revert (failsafe exception to never-fail pattern)
// Rationale: Backend simulates all transactions before execution, so this should never fail in practice.
// If it does fail, it indicates an unexpected critical state (transfer paused, blacklist, insufficient balance
// despite approval, etc.) that requires immediate rollback. Unlike mint, redeem doesn't involve collateral
// transfer first, so revert is safe and appropriate for detecting unexpected state issues.
dlf.burn(order.benefactor, order.token_in_amount);
emit SellOrderCreated(
order.order_id,
order.benefactor,
order.beneficiary,
msg.sender,
order.collateral_asset,
order.token_in_amount,
order.estimated_token_out_amount,
order.fx_rate_approximate,
order.terms_hash,
order.guarantee_type
);
}
/**
* @notice Internal function to handle permit validation and execution
* @param token The token address for permit
* @param benefactor The benefactor (token owner)
* @param requiredAmount The required permit amount
* @param permitParams The permit parameters
* @return Empty string if successful, error message if failed
*/
function _handlePermitExecution(
address token,
address benefactor,
uint128 requiredAmount,
PermitParams calldata permitParams
) internal returns (string memory) {
// Validate permit parameters
string memory failureReason = _validatePermitParamsSafe(requiredAmount, permitParams);
// Execute permit if validation passed
if (bytes(failureReason).length == 0) {
if (!_executePermit(token, benefactor, permitParams)) {
return OrderManagerErrors.PERMIT_EXECUTION_FAILED;
}
}
return failureReason;
}
/**
* @notice Set the token configuration for an asset
* @param asset The asset address
* @param _tokenConfig The token configuration to set
*/
function _setTokenConfig(address asset, TokenConfig memory _tokenConfig) internal {
_tokenConfig.isActive = true;
tokenConfig[asset] = _tokenConfig;
}
/**
* @notice Add a supported asset with its configuration
* @param asset The asset address to add
* @param _tokenConfig The token configuration
*/
function addSupportedAsset(address asset, TokenConfig memory _tokenConfig) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (tokenConfig[asset].isActive || asset == address(0) || asset == address(dlf)) {
revert InvalidAssetAddress();
}
_setTokenConfig(asset, _tokenConfig);
emit AssetAdded(asset);
}
/**
* @notice Compute the current domain separator
* @return The domain separator for the token
*/
function _computeDomainSeparator() internal view returns (bytes32) {
return keccak256(abi.encode(EIP712_DOMAIN, EIP_712_NAME, EIP712_REVISION, block.chainid, address(this)));
}
/**
* @notice Set the token type for a given token
* @param asset The asset address
* @param tokenType The token type to set
*/
function setTokenType(address asset, TokenType tokenType) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (!tokenConfig[asset].isActive) revert UnsupportedAsset();
tokenConfig[asset].tokenType = tokenType;
emit TokenTypeSet(asset, uint256(tokenType));
}
/**
* @notice set the DLF token address
* @param _dlf The DLF token contract address
*/
function setDLFToken(IDLF _dlf) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (address(_dlf) == address(0)) revert InvalidZeroAddress();
dlf = _dlf;
emit DLFSet(address(_dlf));
}
/* --------------- GETTERS --------------- */
/**
* @notice returns whether an address is a whitelisted benefactor
* @param benefactor The address to check
* @return True if the address is a whitelisted benefactor, false otherwise
*/
function isWhitelistedBenefactor(address benefactor) public view returns (bool) {
return _whitelistedBenefactors.contains(benefactor);
}
/**
* @notice returns whether an address is a approved beneficiary per benefactor
* @param benefactor The benefactor address
* @param beneficiary The beneficiary address to check
* @return True if the beneficiary is approved for the benefactor, false otherwise
*/
function isApprovedBeneficiary(address benefactor, address beneficiary) public view returns (bool) {
return _approvedBeneficiariesPerBenefactor[benefactor].contains(beneficiary);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
/**
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
* `nonReentrant` function in the call stack.
*/
function _reentrancyGuardEntered() internal view returns (bool) {
return _status == _ENTERED;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
/**
* @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeTransfer(IERC20 token, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
/**
* @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
* calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
*/
function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(IERC20 token, address spender, uint256 value) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
/**
* @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
uint256 oldAllowance = token.allowance(address(this), spender);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
}
/**
* @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
}
}
/**
* @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
* to be set to zero before setting it to a non-zero value, such as USDT.
*/
function forceApprove(IERC20 token, address spender, uint256 value) internal {
bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);
if (!_callOptionalReturnBool(token, approvalCall)) {
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
_callOptionalReturn(token, approvalCall);
}
}
/**
* @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
* Revert on invalid signature.
*/
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*
* This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
*/
function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
// and not revert is the subcall reverts.
(bool success, bytes memory returndata) = address(token).call(data);
return
success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)
pragma solidity ^0.8.0;
import "../Strings.sol";
/**
* @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
*
* These functions can be used to verify that a message was signed by the holder
* of the private keys of a given address.
*/
library ECDSA {
enum RecoverError {
NoError,
InvalidSignature,
InvalidSignatureLength,
InvalidSignatureS,
InvalidSignatureV // Deprecated in v4.8
}
function _throwError(RecoverError error) private pure {
if (error == RecoverError.NoError) {
return; // no error: do nothing
} else if (error == RecoverError.InvalidSignature) {
revert("ECDSA: invalid signature");
} else if (error == RecoverError.InvalidSignatureLength) {
revert("ECDSA: invalid signature length");
} else if (error == RecoverError.InvalidSignatureS) {
revert("ECDSA: invalid signature 's' value");
}
}
/**
* @dev Returns the address that signed a hashed message (`hash`) with
* `signature` or error string. This address can then be used for verification purposes.
*
* The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
* this function rejects them by requiring the `s` value to be in the lower
* half order, and the `v` value to be either 27 or 28.
*
* IMPORTANT: `hash` _must_ be the result of a hash operation for the
* verification to be secure: it is possible to craft signatures that
* recover to arbitrary addresses for non-hashed data. A safe way to ensure
* this is by receiving a hash of the original message (which may otherwise
* be too long), and then calling {toEthSignedMessageHash} on it.
*
* Documentation for signature generation:
* - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
* - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
*
* _Available since v4.3._
*/
function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
if (signature.length == 65) {
bytes32 r;
bytes32 s;
uint8 v;
// ecrecover takes the signature parameters, and the only way to get them
// currently is to use assembly.
/// @solidity memory-safe-assembly
assembly {
r := mload(add(signature, 0x20))
s := mload(add(signature, 0x40))
v := byte(0, mload(add(signature, 0x60)))
}
return tryRecover(hash, v, r, s);
} else {
return (address(0), RecoverError.InvalidSignatureLength);
}
}
/**
* @dev Returns the address that signed a hashed message (`hash`) with
* `signature`. This address can then be used for verification purposes.
*
* The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
* this function rejects them by requiring the `s` value to be in the lower
* half order, and the `v` value to be either 27 or 28.
*
* IMPORTANT: `hash` _must_ be the result of a hash operation for the
* verification to be secure: it is possible to craft signatures that
* recover to arbitrary addresses for non-hashed data. A safe way to ensure
* this is by receiving a hash of the original message (which may otherwise
* be too long), and then calling {toEthSignedMessageHash} on it.
*/
function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
(address recovered, RecoverError error) = tryRecover(hash, signature);
_throwError(error);
return recovered;
}
/**
* @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
*
* See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
*
* _Available since v4.3._
*/
function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
uint8 v = uint8((uint256(vs) >> 255) + 27);
return tryRecover(hash, v, r, s);
}
/**
* @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
*
* _Available since v4.2._
*/
function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
(address recovered, RecoverError error) = tryRecover(hash, r, vs);
_throwError(error);
return recovered;
}
/**
* @dev Overload of {ECDSA-tryRecover} that receives the `v`,
* `r` and `s` signature fields separately.
*
* _Available since v4.3._
*/
function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
// EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
// unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
// the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
// signatures from current libraries generate a unique signature with an s-value in the lower half order.
//
// If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
// with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
// vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
// these malleable signatures as well.
if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
return (address(0), RecoverError.InvalidSignatureS);
}
// If the signature is valid (and not malleable), return the signer address
address signer = ecrecover(hash, v, r, s);
if (signer == address(0)) {
return (address(0), RecoverError.InvalidSignature);
}
return (signer, RecoverError.NoError);
}
/**
* @dev Overload of {ECDSA-recover} that receives the `v`,
* `r` and `s` signature fields separately.
*/
function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
(address recovered, RecoverError error) = tryRecover(hash, v, r, s);
_throwError(error);
return recovered;
}
/**
* @dev Returns an Ethereum Signed Message, created from a `hash`. This
* produces hash corresponding to the one signed with the
* https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
* JSON-RPC method as part of EIP-191.
*
* See {recover}.
*/
function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
// 32 is the length in bytes of hash,
// enforced by the type signature above
/// @solidity memory-safe-assembly
assembly {
mstore(0x00, "\x19Ethereum Signed Message:\n32")
mstore(0x1c, hash)
message := keccak256(0x00, 0x3c)
}
}
/**
* @dev Returns an Ethereum Signed Message, created from `s`. This
* produces hash corresponding to the one signed with the
* https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
* JSON-RPC method as part of EIP-191.
*
* See {recover}.
*/
function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
}
/**
* @dev Returns an Ethereum Signed Typed Data, created from a
* `domainSeparator` and a `structHash`. This produces hash corresponding
* to the one signed with the
* https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
* JSON-RPC method as part of EIP-712.
*
* See {recover}.
*/
function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
/// @solidity memory-safe-assembly
assembly {
let ptr := mload(0x40)
mstore(ptr, "\x19\x01")
mstore(add(ptr, 0x02), domainSeparator)
mstore(add(ptr, 0x22), structHash)
data := keccak256(ptr, 0x42)
}
}
/**
* @dev Returns an Ethereum Signed Data with intended validator, created from a
* `validator` and `data` according to the version 0 of EIP-191.
*
* See {recover}.
*/
function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
return keccak256(abi.encodePacked("\x19\x00", validator, data));
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.
pragma solidity ^0.8.0;
/**
* @dev Library for managing
* https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
* types.
*
* Sets have the following properties:
*
* - Elements are added, removed, and checked for existence in constant time
* (O(1)).
* - Elements are enumerated in O(n). No guarantees are made on the ordering.
*
* ```solidity
* contract Example {
* // Add the library methods
* using EnumerableSet for EnumerableSet.AddressSet;
*
* // Declare a set state variable
* EnumerableSet.AddressSet private mySet;
* }
* ```
*
* As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
* and `uint256` (`UintSet`) are supported.
*
* [WARNING]
* ====
* Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
* unusable.
* See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
*
* In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
* array of EnumerableSet.
* ====
*/
library EnumerableSet {
// To implement this library for multiple types with as little code
// repetition as possible, we write it in terms of a generic Set type with
// bytes32 values.
// The Set implementation uses private functions, and user-facing
// implementations (such as AddressSet) are just wrappers around the
// underlying Set.
// This means that we can only create new EnumerableSets for types that fit
// in bytes32.
struct Set {
// Storage of set values
bytes32[] _values;
// Position of the value in the `values` array, plus 1 because index 0
// means a value is not in the set.
mapping(bytes32 => uint256) _indexes;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function _add(Set storage set, bytes32 value) private returns (bool) {
if (!_contains(set, value)) {
set._values.push(value);
// The value is stored at length-1, but we add 1 to all indexes
// and use 0 as a sentinel value
set._indexes[value] = set._values.length;
return true;
} else {
return false;
}
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function _remove(Set storage set, bytes32 value) private returns (bool) {
// We read and store the value's index to prevent multiple reads from the same storage slot
uint256 valueIndex = set._indexes[value];
if (valueIndex != 0) {
// Equivalent to contains(set, value)
// To delete an element from the _values array in O(1), we swap the element to delete with the last one in
// the array, and then remove the last element (sometimes called as 'swap and pop').
// This modifies the order of the array, as noted in {at}.
uint256 toDeleteIndex = valueIndex - 1;
uint256 lastIndex = set._values.length - 1;
if (lastIndex != toDeleteIndex) {
bytes32 lastValue = set._values[lastIndex];
// Move the last value to the index where the value to delete is
set._values[toDeleteIndex] = lastValue;
// Update the index for the moved value
set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
}
// Delete the slot where the moved value was stored
set._values.pop();
// Delete the index for the deleted slot
delete set._indexes[value];
return true;
} else {
return false;
}
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function _contains(Set storage set, bytes32 value) private view returns (bool) {
return set._indexes[value] != 0;
}
/**
* @dev Returns the number of values on the set. O(1).
*/
function _length(Set storage set) private view returns (uint256) {
return set._values.length;
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function _at(Set storage set, uint256 index) private view returns (bytes32) {
return set._values[index];
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function _values(Set storage set) private view returns (bytes32[] memory) {
return set._values;
}
// Bytes32Set
struct Bytes32Set {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
return _add(set._inner, value);
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
return _remove(set._inner, value);
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
return _contains(set._inner, value);
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(Bytes32Set storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
return _at(set._inner, index);
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
bytes32[] memory store = _values(set._inner);
bytes32[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
// AddressSet
struct AddressSet {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(AddressSet storage set, address value) internal returns (bool) {
return _add(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(AddressSet storage set, address value) internal returns (bool) {
return _remove(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(AddressSet storage set, address value) internal view returns (bool) {
return _contains(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(AddressSet storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(AddressSet storage set, uint256 index) internal view returns (address) {
return address(uint160(uint256(_at(set._inner, index))));
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(AddressSet storage set) internal view returns (address[] memory) {
bytes32[] memory store = _values(set._inner);
address[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
// UintSet
struct UintSet {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(UintSet storage set, uint256 value) internal returns (bool) {
return _add(set._inner, bytes32(value));
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(UintSet storage set, uint256 value) internal returns (bool) {
return _remove(set._inner, bytes32(value));
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(UintSet storage set, uint256 value) internal view returns (bool) {
return _contains(set._inner, bytes32(value));
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(UintSet storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(UintSet storage set, uint256 index) internal view returns (uint256) {
return uint256(_at(set._inner, index));
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(UintSet storage set) internal view returns (uint256[] memory) {
bytes32[] memory store = _values(set._inner);
uint256[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC1271.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC1271 standard signature validation method for
* contracts as defined in https://eips.ethereum.org/EIPS/eip-1271[ERC-1271].
*
* _Available since v4.1._
*/
interface IERC1271 {
/**
* @dev Should return whether the signature provided is valid for the provided data
* @param hash Hash of the data to be signed
* @param signature Signature byte array associated with _data
*/
function isValidSignature(bytes32 hash, bytes memory signature) external view returns (bytes4 magicValue);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC165.sol)
pragma solidity ^0.8.0;
import "../utils/introspection/IERC165.sol";
<i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*
* ==== Security Considerations
*
* There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
* expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
* considered as an intention to spend the allowance in any specific way. The second is that because permits have
* built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
* take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
* generally recommended is:
*
* ```solidity
* function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
* try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
* doThing(..., value);
* }
*
* function doThing(..., uint256 value) public {
* token.safeTransferFrom(msg.sender, address(this), value);
* ...
* }
* ```
*
* Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
* `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
* {SafeERC20-safeTransferFrom}).
*
* Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
* contracts should have entry points that don't rely on permit.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*
* CAUTION: See Security Considerations above.
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;
/* solhint-disable var-name-mixedcase */
import "./IOrderManagerEvents.sol";
interface IOrderManager is IOrderManagerEvents {
enum Role {
Minter,
Redeemer
}
enum OrderType {
MINT,
REDEEM
}
enum TokenType {
STABLE,
ASSET
}
enum SignatureType {
EIP712,
EIP1271
}
struct Signature {
SignatureType signature_type;
bytes signature_bytes;
}
/**
* @notice Core order structure for the DLF settlement system
* @dev This struct represents a user's intent to buy or sell DLF tokens. Orders are created
* off-chain by the backend RFQ system, signed with EIP-712, and executed on-chain through
* two distinct settlement paths depending on order type.
*
* System Context - Two Settlement Paths:
*
* **MINT Orders (Atomic/Immediate Settlement)**:
* 1. **RFQ Quote**: Backend provides guaranteed quote with rates and amounts
* 2. **Order Signing**: User signs order accepting the quote (EIP-712)
* 3. **Atomic Execution**: On-chain execution happens immediately:
* - User's collateral transferred to custody wallet
* - DLF tokens minted instantly to beneficiary
* 4. **No Batching**: Each mint order executes independently and immediately
*
* **REDEEM Orders (Batch Settlement)**:
* 1. **Order Signing**: User signs redeem order (EIP-712)
* 2. **DLF Burn**: DLF tokens burned from benefactor on submission
* 3. **Settlement Process**: Collateral distribution handled through off-chain settlement
* 4. **Collateral Transfer**: Collateral sent to beneficiary after settlement completion
*
* The hybrid design balances immediate token issuance for mints with compliant
* batch processing for redeems, enabling regulatory compliance while maintaining
* on-chain transparency and immutability.
*/
struct Order {
/// @notice Unique identifier for this order (used for tracking and deduplication)
string order_id;
/// @notice Type of operation: MINT (buy DLF with collateral) or REDEEM (sell DLF for collateral)
OrderType order_type;
/// @notice Unix timestamp when this order signature expires (prevents replay attacks)
uint120 expiry;
/// @notice User's nonce for signature uniqueness (prevents double-spending)
uint128 nonce;
/// @notice Address that signed this order and will provide/receive assets
address benefactor;
/// @notice Address that will receive the output tokens (can be different from benefactor)
address beneficiary;
/// @notice Token contract address for collateral (USDC/TRYTF for mints, DLF for redeems)
address collateral_asset;
/// @notice Amount of input tokens for this order (in token's native decimals)
uint128 token_in_amount;
/// @notice Expected amount of output tokens from this order (in token's native decimals)
uint128 estimated_token_out_amount;
/// @notice Exchange rate used for this order (for analytics and settlement verification)
uint128 fx_rate_approximate;
/// @notice Cryptographic reference to applicable terms and conditions
bytes32 terms_hash;
/// @notice Type of guarantee for this order
GuaranteeType guarantee_type;
}
struct TokenConfig {
/// @notice tracks asset type (STABLE or ASSET)
TokenType tokenType;
/// @notice tracks if the asset is active
bool isActive;
}
struct PermitParams {
uint256 value; // Amount to approve
uint256 deadline; // Permit deadline
uint8 v; // Signature v
bytes32 r; // Signature r
bytes32 s; // Signature s
}
// Errors that are still used with revert statements
error InvalidAddress();
error InvalidZeroAddress();
error InvalidAssetAddress();
error InvalidBenefactorAddress();
error InvalidBeneficiaryAddress();
error InvalidSettlementVehicleAddress();
error NoAssetsProvided();
error UnsupportedAsset();
error TransferFailed();
function hashOrder(Order calldata order) external view returns (bytes32);
function verifyNonce(address sender, uint128 nonce)
external
view
returns (string memory errorMessage, uint128, uint256, uint256);
function verifyOrder(
Order calldata order,
Signature calldata signature
) external view returns (string memory errorMessage);
function mint(Order calldata order, Signature calldata signature, address settlementContract) external;
function redeem(Order calldata order, Signature calldata signature, address settlementContract) external;
function mintWithApproval(
Order calldata order,
Signature calldata signature,
address settlementContract,
PermitParams calldata permitParams
) external;
function redeemWithApproval(
Order calldata order,
Signature calldata signature,
address settlementContract,
PermitParams calldata permitParams
) external;
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.26;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol";
interface IDLF is IERC20, IERC20Permit, IERC20Metadata {
function mint(address _to, uint256 _amount) external;
function burn(address from, uint256 amount) external;
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.26;
/**
* @title OrderManagerErrors
* @notice Library containing all error message constants for OrderManager
*/
library OrderManagerErrors {
// Failure reason strings
string internal constant INVALID_SETTLEMENT_VEHICLE = "InvalidSettlementVehicle";
string internal constant INVALID_ORDER_TYPE = "InvalidOrderType";
string internal constant INVALID_EIP712_SIGNATURE = "InvalidEIP712Signature";
string internal constant INVALID_EIP1271_SIGNATURE = "InvalidEIP1271Signature";
string internal constant EIP1271_VALIDATION_FAILED = "EIP1271ValidationFailed";
string internal constant UNKNOWN_SIGNATURE_TYPE = "UnknownSignatureType";
string internal constant BENEFACTOR_NOT_WHITELISTED = "BenefactorNotWhitelisted";
string internal constant BENEFICIARY_NOT_APPROVED = "BeneficiaryNotApproved";
string internal constant UNSUPPORTED_ASSET = "UnsupportedAsset";
string internal constant INVALID_ADDRESS = "InvalidAddress";
string internal constant INVALID_AMOUNT = "InvalidAmount";
string internal constant INVALID_FX_RATE = "InvalidFxRate";
string internal constant SIGNATURE_EXPIRED = "SignatureExpired";
string internal constant TRANSFER_FAILED = "TransferFailed";
string internal constant PERMIT_AMOUNT_INSUFFICIENT = "PermitAmountInsufficient";
string internal constant PERMIT_DEADLINE_INVALID = "PermitDeadlineInvalid";
string internal constant PERMIT_EXECUTION_FAILED = "PermitExecutionFailed";
string internal constant INVALID_TERMS_HASH = "InvalidTermsHash";
string internal constant INVALID_NONCE = "InvalidNonce";
string internal constant NONCE_ALREADY_USED = "NonceAlreadyUsed";
string internal constant INVALID_GUARANTEE_TYPE = "InvalidGuaranteeType";
string internal constant DLF_NOT_INITIALIZED = "DLFNotInitialized";
string internal constant INVALID_SIGNATURE_FORMAT = "InvalidSignatureFormat";
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.26;
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/interfaces/IERC5313.sol";
import "./interfaces/ISingleAdminAccessControl.sol";
/**
* @title SingleAdminAccessControl
* @notice SingleAdminAccessControl is a contract that provides a single admin role
* @notice This contract is a simplified alternative to OpenZeppelin's AccessControlDefaultAdminRules
*/
abstract contract SingleAdminAccessControl is IERC5313, ISingleAdminAccessControl, AccessControl {
address private _currentDefaultAdmin;
address private _pendingDefaultAdmin;
modifier notAdmin(bytes32 role) {
if (role == DEFAULT_ADMIN_ROLE) revert InvalidAdminChange();
_;
}
/// @notice Transfer the admin role to a new address
/// @notice This can ONLY be executed by the current admin
/// @param newAdmin address
function transferAdmin(address newAdmin) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (newAdmin == msg.sender) revert InvalidAdminChange();
_pendingDefaultAdmin = newAdmin;
emit AdminTransferRequested(_currentDefaultAdmin, newAdmin);
}
function acceptAdmin() external {
if (msg.sender != _pendingDefaultAdmin) revert NotPendingAdmin();
_grantRole(DEFAULT_ADMIN_ROLE, msg.sender);
}
/// @notice grant a role
/// @notice can only be executed by the current single admin
/// @notice admin role cannot be granted externally
/// @param role bytes32
/// @param account address
function grantRole(bytes32 role, address account) public override onlyRole(DEFAULT_ADMIN_ROLE) notAdmin(role) {
_grantRole(role, account);
}
/// @notice revoke a role
/// @notice can only be executed by the current admin
/// @notice admin role cannot be revoked
/// @param role bytes32
/// @param account address
function revokeRole(bytes32 role, address account) public override onlyRole(DEFAULT_ADMIN_ROLE) notAdmin(role) {
_revokeRole(role, account);
}
/// @notice renounce the role of msg.sender
/// @notice admin role cannot be renounced
/// @param role bytes32
/// @param account address
function renounceRole(bytes32 role, address account) public virtual override notAdmin(role) {
super.renounceRole(role, account);
}
/**
* @dev See {IERC5313-owner}.
*/
function owner() public view virtual returns (address) {
return _currentDefaultAdmin;
}
/**
* @notice no way to change admin without removing old admin first
*/
function _grantRole(bytes32 role, address account) internal override {
if (role == DEFAULT_ADMIN_ROLE) {
emit AdminTransferred(_currentDefaultAdmin, account);
_revokeRole(DEFAULT_ADMIN_ROLE, _currentDefaultAdmin);
_currentDefaultAdmin = account;
delete _pendingDefaultAdmin;
}
super._grantRole(role, account);
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 amount) external returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
*
* Furthermore, `isContract` will also return true if the target contract within
* the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
* which only has an effect at the end of a transaction.
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
import "./math/Math.sol";
import "./math/SignedMath.sol";
/**
* @dev String operations.
*/
library Strings {
bytes16 private constant _SYMBOLS = "0123456789abcdef";
uint8 private constant _ADDRESS_LENGTH = 20;
/**
* @dev Converts a `uint256` to its ASCII `string` decimal representation.
*/
function toString(uint256 value) internal pure returns (string memory) {
unchecked {
uint256 length = Math.log10(value) + 1;
string memory buffer = new string(length);
uint256 ptr;
/// @solidity memory-safe-assembly
assembly {
ptr := add(buffer, add(32, length))
}
while (true) {
ptr--;
/// @solidity memory-safe-assembly
assembly {
mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
}
value /= 10;
if (value == 0) break;
}
return buffer;
}
}
/**
* @dev Converts a `int256` to its ASCII `string` decimal representation.
*/
function toString(int256 value) internal pure returns (string memory) {
return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
*/
function toHexString(uint256 value) internal pure returns (string memory) {
unchecked {
return toHexString(value, Math.log256(value) + 1);
}
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
*/
function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
bytes memory buffer = new bytes(2 * length + 2);
buffer[0] = "0";
buffer[1] = "x";
for (uint256 i = 2 * length + 1; i > 1; --i) {
buffer[i] = _SYMBOLS[value & 0xf];
value >>= 4;
}
require(value == 0, "Strings: hex length insufficient");
return string(buffer);
}
/**
* @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
*/
function toHexString(address addr) internal pure returns (string memory) {
return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
}
/**
* @dev Returns true if the two strings are equal.
*/
function equal(string memory a, string memory b) internal pure returns (bool) {
return keccak256(bytes(a)) == keccak256(bytes(b));
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC165 standard, as defined in the
* https://eips.ethereum.org/EIPS/eip-165[EIP].
*
* Implementers can declare support of contract interfaces, which can then be
* queried by others ({ERC165Checker}).
*
* For an implementation, see {ERC165}.
*/
interface IERC165 {
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external view returns (bool);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;
/* solhint-disable var-name-mixedcase */
interface IOrderManagerEvents {
/// @notice Event emitted when contract receives ETH
event Received(address, uint256);
/// @notice Event emitted when a buy order is created
enum GuaranteeType {
NO_GUARANTEE,
GUARANTEE
}
/// @notice Event emitted when a buy order is created
event BuyOrderCreated(
string indexed order_id,
address indexed benefactor,
address indexed beneficiary,
address minter,
address collateral_asset,
uint256 token_in_amount,
uint256 estimated_token_out_amount,
uint256 fx_rate_approximate,
bytes32 terms_hash,
GuaranteeType guarantee_type
);
/// @notice Event emitted when a sell order is created
event SellOrderCreated(
string indexed order_id,
address indexed benefactor,
address indexed beneficiary,
address redeemer,
address collateral_asset,
uint256 token_in_amount,
uint256 estimated_token_out_amount,
uint256 fx_rate_approximate,
bytes32 terms_hash,
GuaranteeType guarantee_type
);
/// @notice Event emitted when a supported asset is added
event AssetAdded(address indexed asset);
/// @notice Event emitted when a supported asset is removed
event AssetRemoved(address indexed asset);
/// @notice Event emitted when a benefactor address is added
event BenefactorAdded(address indexed benefactor);
/// @notice Event emitted when a beneficiary address is added or updated
event BeneficiaryAdded(address indexed benefactor, address indexed beneficiary);
/// @notice Event emitted when a benefactor address is removed
event BenefactorRemoved(address indexed benefactor);
/// @notice Event emitted when a beneficiary address is removed
event BeneficiaryRemoved(address indexed benefactor, address indexed beneficiary);
/// @notice Event emitted when a settlement vehicle address is added
event SettlementVehicleAddressAdded(address indexed settlementVehicle);
/// @notice Event emitted when a settlement vehicle address is removed
event SettlementVehicleAddressRemoved(address indexed settlementVehicle);
/// @notice Event emitted when assets are moved to custody provider wallet
event CustodyTransfer(address indexed wallet, address indexed asset, uint256 amount);
/// @notice Event emitted when DLF token is set
event DLFSet(address indexed dlf);
/// @notice Event emitted when the token type for a token is set.
event TokenTypeSet(address indexed token, uint256 tokenType);
/// @notice Event emitted when global mint and redeem are disabled.
event DisableMintRedeem(address indexed sender);
/// @notice Event emitted when an order fails validation
event OrderFailed(
string indexed order_id,
address indexed beneficiary,
string reason
);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)
pragma solidity ^0.8.0;
import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";
/**
* @dev Contract module that allows children to implement role-based access
* control mechanisms. This is a lightweight version that doesn't allow enumerating role
* members except through off-chain means by accessing the contract event logs. Some
* applications may benefit from on-chain enumerability, for those cases see
* {AccessControlEnumerable}.
*
* Roles are referred to by their `bytes32` identifier. These should be exposed
* in the external API and be unique. The best way to achieve this is by
* using `public constant` hash digests:
*
* ```solidity
* bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
* ```
*
* Roles can be used to represent a set of permissions. To restrict access to a
* function call, use {hasRole}:
*
* ```solidity
* function foo() public {
* require(hasRole(MY_ROLE, msg.sender));
* ...
* }
* ```
*
* Roles can be granted and revoked dynamically via the {grantRole} and
* {revokeRole} functions. Each role has an associated admin role, and only
* accounts that have a role's admin role can call {grantRole} and {revokeRole}.
*
* By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
* that only accounts with this role will be able to grant or revoke other
* roles. More complex role relationships can be created by using
* {_setRoleAdmin}.
*
* WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
* grant and revoke this role. Extra precautions should be taken to secure
* accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
* to enforce additional security measures for this role.
*/
abstract contract AccessControl is Context, IAccessControl, ERC165 {
struct RoleData {
mapping(address => bool) members;
bytes32 adminRole;
}
mapping(bytes32 => RoleData) private _roles;
bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
/**
* @dev Modifier that checks that an account has a specific role. Reverts
* with a standardized message including the required role.
*
* The format of the revert reason is given by the following regular expression:
*
* /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
*
* _Available since v4.1._
*/
modifier onlyRole(bytes32 role) {
_checkRole(role);
_;
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
}
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
return _roles[role].members[account];
}
/**
* @dev Revert with a standard message if `_msgSender()` is missing `role`.
* Overriding this function changes the behavior of the {onlyRole} modifier.
*
* Format of the revert message is described in {_checkRole}.
*
* _Available since v4.6._
*/
function _checkRole(bytes32 role) internal view virtual {
_checkRole(role, _msgSender());
}
/**
* @dev Revert with a standard message if `account` is missing `role`.
*
* The format of the revert reason is given by the following regular expression:
*
* /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
*/
function _checkRole(bytes32 role, address account) internal view virtual {
if (!hasRole(role, account)) {
revert(
string(
abi.encodePacked(
"AccessControl: account ",
Strings.toHexString(account),
" is missing role ",
Strings.toHexString(uint256(role), 32)
)
)
);
}
}
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
return _roles[role].adminRole;
}
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleGranted} event.
*/
function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
_grantRole(role, account);
}
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleRevoked} event.
*/
function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
_revokeRole(role, account);
}
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been revoked `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `account`.
*
* May emit a {RoleRevoked} event.
*/
function renounceRole(bytes32 role, address account) public virtual override {
require(account == _msgSender(), "AccessControl: can only renounce roles for self");
_revokeRole(role, account);
}
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event. Note that unlike {grantRole}, this function doesn't perform any
* checks on the calling account.
*
* May emit a {RoleGranted} event.
*
* [WARNING]
* ====
* This function should only be called from the constructor when setting
* up the initial roles for the system.
*
* Using this function in any other way is effectively circumventing the admin
* system imposed by {AccessControl}.
* ====
*
* NOTE: This function is deprecated in favor of {_grantRole}.
*/
function _setupRole(bytes32 role, address account) internal virtual {
_grantRole(role, account);
}
/**
* @dev Sets `adminRole` as ``role``'s admin role.
*
* Emits a {RoleAdminChanged} event.
*/
function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
bytes32 previousAdminRole = getRoleAdmin(role);
_roles[role].adminRole = adminRole;
emit RoleAdminChanged(role, previousAdminRole, adminRole);
}
/**
* @dev Grants `role` to `account`.
*
* Internal function without access restriction.
*
* May emit a {RoleGranted} event.
*/
function _grantRole(bytes32 role, address account) internal virtual {
if (!hasRole(role, account)) {
_roles[role].members[account] = true;
emit RoleGranted(role, account, _msgSender());
}
}
/**
* @dev Revokes `role` from `account`.
*
* Internal function without access restriction.
*
* May emit a {RoleRevoked} event.
*/
function _revokeRole(bytes32 role, address account) internal virtual {
if (hasRole(role, account)) {
_roles[role].members[account] = false;
emit RoleRevoked(role, account, _msgSender());
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC5313.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface for the Light Contract Ownership Standard.
*
* A standardized minimal interface required to identify an account that controls a contract
*
* _Available since v4.9._
*/
interface IERC5313 {
/**
* @dev Gets the address of the owner.
*/
function owner() external view returns (address);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;
interface ISingleAdminAccessControl {
error InvalidAdminChange();
error NotPendingAdmin();
event AdminTransferred(address indexed oldAdmin, address indexed newAdmin);
event AdminTransferRequested(address indexed oldAdmin, address indexed newAdmin);
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)
pragma solidity ^0.8.0;
/**
* @dev Standard math utilities missing in the Solidity language.
*/
library Math {
enum Rounding {
Down, // Toward negative infinity
Up, // Toward infinity
Zero // Toward zero
}
/**
* @dev Returns the largest of two numbers.
*/
function max(uint256 a, uint256 b) internal pure returns (uint256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two numbers.
*/
function min(uint256 a, uint256 b) internal pure returns (uint256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two numbers. The result is rounded towards
* zero.
*/
function average(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b) / 2 can overflow.
return (a & b) + (a ^ b) / 2;
}
/**
* @dev Returns the ceiling of the division of two numbers.
*
* This differs from standard division with `/` in that it rounds up instead
* of rounding down.
*/
function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b - 1) / b can overflow on addition, so we distribute.
return a == 0 ? 0 : (a - 1) / b + 1;
}
/**
* @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
* @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
* with further edits by Uniswap Labs also under MIT license.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
unchecked {
// 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
// use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
// variables such that product = prod1 * 2^256 + prod0.
uint256 prod0; // Least significant 256 bits of the product
uint256 prod1; // Most significant 256 bits of the product
assembly {
let mm := mulmod(x, y, not(0))
prod0 := mul(x, y)
prod1 := sub(sub(mm, prod0), lt(mm, prod0))
}
// Handle non-overflow cases, 256 by 256 division.
if (prod1 == 0) {
// Solidity will revert if denominator == 0, unlike the div opcode on its own.
// The surrounding unchecked block does not change this fact.
// See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
return prod0 / denominator;
}
// Make sure the result is less than 2^256. Also prevents denominator == 0.
require(denominator > prod1, "Math: mulDiv overflow");
///////////////////////////////////////////////
// 512 by 256 division.
///////////////////////////////////////////////
// Make division exact by subtracting the remainder from [prod1 prod0].
uint256 remainder;
assembly {
// Compute remainder using mulmod.
remainder := mulmod(x, y, denominator)
// Subtract 256 bit number from 512 bit number.
prod1 := sub(prod1, gt(remainder, prod0))
prod0 := sub(prod0, remainder)
}
// Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
// See https://cs.stackexchange.com/q/138556/92363.
// Does not overflow because the denominator cannot be zero at this stage in the function.
uint256 twos = denominator & (~denominator + 1);
assembly {
// Divide denominator by twos.
denominator := div(denominator, twos)
// Divide [prod1 prod0] by twos.
prod0 := div(prod0, twos)
// Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
twos := add(div(sub(0, twos), twos), 1)
}
// Shift in bits from prod1 into prod0.
prod0 |= prod1 * twos;
// Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
// that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
// four bits. That is, denominator * inv = 1 mod 2^4.
uint256 inverse = (3 * denominator) ^ 2;
// Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
// in modular arithmetic, doubling the correct bits in each step.
inverse *= 2 - denominator * inverse; // inverse mod 2^8
inverse *= 2 - denominator * inverse; // inverse mod 2^16
inverse *= 2 - denominator * inverse; // inverse mod 2^32
inverse *= 2 - denominator * inverse; // inverse mod 2^64
inverse *= 2 - denominator * inverse; // inverse mod 2^128
inverse *= 2 - denominator * inverse; // inverse mod 2^256
// Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
// This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
// less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
// is no longer required.
result = prod0 * inverse;
return result;
}
}
/**
* @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
uint256 result = mulDiv(x, y, denominator);
if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
result += 1;
}
return result;
}
/**
* @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
*
* Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
*/
function sqrt(uint256 a) internal pure returns (uint256) {
if (a == 0) {
return 0;
}
// For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
//
// We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
// `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
//
// This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
// → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
// → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
//
// Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
uint256 result = 1 << (log2(a) >> 1);
// At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
// since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
// every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
// into the expected uint128 result.
unchecked {
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
return min(result, a / result);
}
}
/**
* @notice Calculates sqrt(a), following the selected rounding direction.
*/
function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = sqrt(a);
return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
}
}
/**
* @dev Return the log in base 2, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 128;
}
if (value >> 64 > 0) {
value >>= 64;
result += 64;
}
if (value >> 32 > 0) {
value >>= 32;
result += 32;
}
if (value >> 16 > 0) {
value >>= 16;
result += 16;
}
if (value >> 8 > 0) {
value >>= 8;
result += 8;
}
if (value >> 4 > 0) {
value >>= 4;
result += 4;
}
if (value >> 2 > 0) {
value >>= 2;
result += 2;
}
if (value >> 1 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 2, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log2(value);
return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 10, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >= 10 ** 64) {
value /= 10 ** 64;
result += 64;
}
if (value >= 10 ** 32) {
value /= 10 ** 32;
result += 32;
}
if (value >= 10 ** 16) {
value /= 10 ** 16;
result += 16;
}
if (value >= 10 ** 8) {
value /= 10 ** 8;
result += 8;
}
if (value >= 10 ** 4) {
value /= 10 ** 4;
result += 4;
}
if (value >= 10 ** 2) {
value /= 10 ** 2;
result += 2;
}
if (value >= 10 ** 1) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 10, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log10(value);
return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 256, rounded down, of a positive value.
* Returns 0 if given 0.
*
* Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
*/
function log256(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 16;
}
if (value >> 64 > 0) {
value >>= 64;
result += 8;
}
if (value >> 32 > 0) {
value >>= 32;
result += 4;
}
if (value >> 16 > 0) {
value >>= 16;
result += 2;
}
if (value >> 8 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 256, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log256(value);
return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)
pragma solidity ^0.8.0;
/**
* @dev Standard signed math utilities missing in the Solidity language.
*/
library SignedMath {
/**
* @dev Returns the largest of two signed numbers.
*/
function max(int256 a, int256 b) internal pure returns (int256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two signed numbers.
*/
function min(int256 a, int256 b) internal pure returns (int256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two signed numbers without overflow.
* The result is rounded towards zero.
*/
function average(int256 a, int256 b) internal pure returns (int256) {
// Formula from the book "Hacker's Delight"
int256 x = (a & b) + ((a ^ b) >> 1);
return x + (int256(uint256(x) >> 255) & (a ^ b));
}
/**
* @dev Returns the absolute unsigned value of a signed value.
*/
function abs(int256 n) internal pure returns (uint256) {
unchecked {
// must be unchecked in order to support `n = type(int256).min`
return uint256(n >= 0 ? n : -n);
}
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)
pragma solidity ^0.8.0;
/**
* @dev External interface of AccessControl declared to support ERC165 detection.
*/
interface IAccessControl {
/**
* @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
*
* `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
* {RoleAdminChanged} not being emitted signaling this.
*
* _Available since v3.1._
*/
event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);
/**
* @dev Emitted when `account` is granted `role`.
*
* `sender` is the account that originated the contract call, an admin role
* bearer except when using {AccessControl-_setupRole}.
*/
event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Emitted when `account` is revoked `role`.
*
* `sender` is the account that originated the contract call:
* - if using `revokeRole`, it is the admin role bearer
* - if using `renounceRole`, it is the role bearer (i.e. `account`)
*/
event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) external view returns (bool);
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {AccessControl-_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) external view returns (bytes32);
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function grantRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function revokeRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been granted `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `account`.
*/
function renounceRole(bytes32 role, address account) external;
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
function _contextSuffixLength() internal view virtual returns (uint256) {
return 0;
}
} <i class='far fa-question-circle text-muted ms-2' data-bs-trigger='hover' data-bs-toggle='tooltip' data-bs-html='true' data-bs-title='Click on the check box to select individual contract to compare. Only 1 contract can be selected from each side.'></i>
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
* @dev Implementation of the {IERC165} interface.
*
* Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
* for the additional interface id that will be supported. For example:
*
* ```solidity
* function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
* return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
* }
* ```
*
* Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
*/
abstract contract ERC165 is IERC165 {
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IERC165).interfaceId;
}
}